;$DIR=/opt/topspin/exp/stan/nmr/lists/pp/user/
;$CLASS=HighRes
;$DIM=2D
;   F1 -> J(S) evolution, F2 -> directly acquired
;$TYPE=heteronuclear correlation
;$COMMENT=dual channel broadband HSQC experiment
;   Rectangular pi rotations replaced with six-pulse SCRAM blocks (4 on I, 2 on S)
;      Block I:   (i) forward inept
;      Block II:  (j) J(S) evolution
;      Block III: (v) reverse inept
;   Interval T(i) adjusted by d61, set T(i) = 2/|JII| to suppress homonuclear J modulation
;   Interval T(v) adjusted by d62, set T(i) = 2/|JII| to suppress homonuclear J modulation
;   Phase-sensitive using States/TPPI
;   I : observe nucleus (f1)
;   S : evolve nucleus (f2)
; OPTIONS:
; WARNING: This pulse sequence is provided only as a guide for experienced users to implement with due care. It may contain mistakes. Improper setting of parameters may cause damage to the spectrometer, probe, or sample. All protections have been removed! The authors nor their employers accept any responsibility for use of this experiment. Any copy or modification of this sequence should contain this header.

;ns 32-step phase cycle (8-step min)
;spnam7 I sweep pulse
;spnam8 S sweep pulse
;p1 I exc pulse (pl1)
;p3 I sto pulse (pl1)
;p4 S exc pulse (pl2)
;p6 S sto pulse (pl2)
;p7 I sweep pulse (a)
;p8 S sweep pulse (b)
;pl1 I pulse power
;pl2 S pulse power
;pl12 decoupling power
;d0 initial t1 value
;d1 recycle delay
;d8 = 1/|8J|
;d40 set at runtime
;d61 adds to c(i), d(i) delays (adds 4*d61 to total time)
;d62 adds to c(v), d(v) delays (adds 4*d62 to total time)


define pulse j                ;displays targeted J (in Hz, listed as µsec)
 "j=1s/(8*d8)"
define delay dic              ;scram inept 'c' delay
 "dic=p8/2+d61"
define delay did              ;scram inept 'd' delay
 "did=d8+d61"
define delay die              ;scram inept 'e' delay
 "die=0"
define delay dif              ;scram inept 'f' delay
 "dif=d8+p8/2"
define delay djc              ;scram J(S) evolution 'c' delay
 "djc=0"
define delay djd              ;scram J(S) evolution 'd' delay -- nonincremented part
 "djd=0"
define delay dje              ;scram J(S) evolution 'e' delay
 "dje=0"
define delay djf              ;scram J(S) evolution 'f' delay -- nonincremented part
 "djf=0"
define delay dvc              ;scram reverse inept 'c' delay
 "dvc=p8/2+d62"
define delay dvd              ;scram reverse inept 'd' delay
 "dvd=d8+d62"
define delay dve              ;scram reverse inept 'e' delay
 "dve=0"
define delay dvf              ;scram reverse inept 'f' delay
 "dvf=d8+p8/2"
define delay daq
 "daq=dvc-de"
define delay tti              ;total scram inept interval time
 "tti=2*(dic+did+die+dif)+4*p7+2*p8"
define delay ttv              ;total scram reverse inept interval time
 "ttv=2*(dvc+dvd+dve+dvf)+4*p7+2*p8"

"in0=inf1"
"acqt0=0"


1  ze
   "j=j"                      ;show targeted j value in 'ased'
   10m
2  d1 do:f2
   "d40=d0/4"                 ;for 1/2/1 split t1 evolution
3  (p1 pl1 ph1):f1            ;I exc
   dic                        ;symmetric forward scram inept block: c, d, e, f, f, e, d, c
   (p7:sp7 ph0):f1
   did
   (p8:sp8 ph0):f2
   die
   (p7:sp7 ph0):f1
   dif
   dif
   (p7:sp7 ph0):f1
   die
   (p8:sp8 ph0):f2
   did
   (p7:sp7 ph0):f1
   dic
4  (p3 pl1 ph3):f1            ;I sto/S exc
   (p4 pl2 ph4):f2            ;symmetric scram J(S) evolution block: c, d, e, f, f, e, d, c
   djc                        ;'c' delay
   (p7:sp7 ph0):f1
   djd                        ;'d' delay
   d40   
   (p8:sp8 ph0):f2
   dje                        ;'e' delay
   (p7:sp7 ph0):f1
   djf
   d40                        ;'f' delay
   d40
   djf
   (p7:sp7 ph0):f1
   dje
   (p8:sp8 ph0):f2
   d40
   djd
   (p7:sp7 ph0):f1
   djc
   (p6 pl2 ph6):f2            ;S sto/I exc
5  (p1 pl1 ph9):f1            ;symmetric reverse scram inept block: c, d, e, f, f, e, d, c   
   dvc
   (p7:sp7 ph0):f1
   dvd            
   (p8:sp8 ph0):f2
   dve
   (p7:sp7 ph0):f1
   dvf
   dvf
   (p7:sp7 ph0):f1
   dve
   (p8:sp8 ph0):f2
   dvd
   (p7:sp7 ph0):f1
   daq                                 
   go=2 ph31 cpds2:f2 finally do:f2
   d1 do:f2 mc #0 to 2 F1PH(calph(ph6), caldel(d0))
exit

ph0=          0
ph1=          0
ph3=        {{3}*4}^2
ph4=          0 1 2 3
ph6=          2 1 0 3
ph9=        {{1}*8}^1^2^3
ph31=       {{2 0 2 0}^2}^1^2^3