;$DIR=/opt/topspin/exp/stan/nmr/lists/pp/user/
;$CLASS=HighRes
;$DIM=1D
;   F1 -> directly acquired
;$TYPE=
;$COMMENT=dual channel broadband INEPT experiment
;   Rectangular pi rotations replaced with six-pulse SCRAM block (4 on I, 2 on S)
;      Block I:   (i) forward inept
;   Interval T adjusted by d61, set T = 2/|JII| to suppress homonuclear J modulation
;   Phase cycle filters out intrinsic S magnetization yielding pure z1-multiplets
;   I : source nucleus (f2)
;   S : observe nucleus (f1)
; OPTIONS: 
; WARNING: This pulse sequence is provided only as a guide for experienced users to implement with due care. It may contain mistakes. Improper setting of parameters may cause damage to the spectrometer, probe, or sample. All protections have been removed! The authors nor their employers accept any responsibility for use of this experiment. Any copy or modification of this sequence should contain this header.

;ns 4-step phase cycle
;spnam7 I sweep pulse
;spnam8 S sweep pulse
;p1 I exc pulse (pl2)
;p3 I sto pulse (pl2)
;p4 S exc pulse (pl1)
;p7 I sweep pulse (a)
;p8 S sweep pulse (b)
;pl1 S pulse power
;pl2 I pulse power
;pl12 decoupling power
;d0 initial t1 value
;d1 recycle delay
;d8 = 1/|8J|
;d61 adds to c and d delays (adds 4*d61 to total time)


define pulse j                ;displays targeted J (in Hz, listed as µsec)
 "j=1s/(8*d8)"
define delay dic              ;scram inept 'c' delay
 "dic=p8/2+d61"
define delay did              ;scram inept 'd' delay
 "did=d8+d61"
define delay die              ;scram inept 'e' delay
 "die=0"
define delay dif              ;scram inept 'f' delay
 "dif=d8+p8/2"
define delay tt              ;total (i) interval time
 "tt=2*(dic+did+die+dif)+4*p7+2*p8"

"acqt0=-p1/2"


1  ze
   "j=j"                      ;show targeted j value in 'ased'
   10m
2  d1 do:f2
3  (p1 pl2 ph1):f2            ;I exc
   dic                        ;symmetric forward scram inept block: c, d, e, f, f, e, d, c
   (p7:sp7 ph0):f2
   did
   (p8:sp8 ph0):f1
   die
   (p7:sp7 ph0):f2
   dif
   dif
   (p7:sp7 ph0):f2
   die
   (p8:sp8 ph0):f1
   did
   (p7:sp7 ph0):f2
   dic
   (p3 pl2 ph3):f2            ;I sto/S exc
   (p4 pl1 ph4):f1
   go=2 ph31 cpds2:f2 finally do:f2
   d1 do:f2 mc #0 to 2 F0(zd)
exit 


ph0=          0
ph1=          0
ph3=        {{3}*2}^2
ph4=          0 2
ph31=        {0 2}^2